Move Selected Finder Item(s) to folder?

Questions & Suggestions
9

Hey Aaron,

Sure, that's easy.

See this post to get a tool to create a relative-alias for your destination folder.

Putting relative-aliases on the Clipboard

Here's pretty much the simplest possible script:

------------------------------------------------------------------------------

# This is a relative-alias
set destinationFolder to alias ((path to downloads folder as text) & "YourFolderName")

tell application "Finder"
   set finderSelectionList to selection as alias list
   if length of finderSelectionList = 0 then error "No files were selected in the Finder!"
   move finderSelectionList to destinationFolder
end tell

------------------------------------------------------------------------------

Here's the same script with better error-checking:

------------------------------------------------------------------------------
# Auth: Christopher Stone
# dCre: 2017/03/19 16:40
# dMod: 2017/03/19 16:43
# Appl: Finder
# Task: Move the selected items to a destination folder
# Libs: None
# Osax: None
# Tags: @Applescript, @Script, @Finder @Move, @Selected, @Items, @Destination, @ccstone
------------------------------------------------------------------------------

try
   
   # This is a relative-alias
   set destinationFolder to alias ((path to downloads folder as text) & "YourFolderName")
   
   tell application "Finder"
      set finderSelectionList to selection as alias list
      if length of finderSelectionList = 0 then error "No files were selected in the Finder!"
      move finderSelectionList to destinationFolder
   end tell
   
on error e number n
   set e to e & return & return & "Num: " & n
   if n ≠ -128 then
      try
         tell application (path to frontmost application as text) to set ddButton to button returned of ¬
            (display dialog e with title "ERROR!" buttons {"Copy Error Message", "Cancel", "OK"} ¬
               default button "OK" giving up after 30)
         if ddButton = "Copy Error Message" then set the clipboard to e
      end try
   end if
end try

------------------------------------------------------------------------------

-Chris