@del_84, glad it worked for you. BTW, I just uploaded an improved version within my original post. The version I had previously uploaded would not work properly if you were viewing Finder files as List and you selected a file below the top of the hierarchy. For example:
The reason the original version failed is because this snippet of AppleScript does not return the parent directory under those circumstances:
tell application "Finder"
set file_Parent to (folder of the front Finder window) as alias
end tell
I should have caught that; sorry. 
On a positive note, both versions correctly increment the integer suffix no matter the base file selected. For example, if a folder included the following files:
a.txt
a1.txt
a2.txt
The next file created (via copy) would be a3.txt regardless of the file selected. One advantage of this behavior is that you can select one of the files and repeatedly trigger the macro if you want to create multiple copies.
For those interested, here's the full AppleScript that was in the original macro:
AppleScript-image
set kmInst to system attribute "KMINSTANCE"
tell application "Keyboard Maestro Engine"
set file_Prefix to getvariable "local_Prefix" instance kmInst
set file_Suffix to getvariable "local_Suffix" instance kmInst
set file_Extension to getvariable "local_Extension" instance kmInst
end tell
if file_Extension is not "" then
set file_Extension to "." & file_Extension
end if
tell application "Finder"
set file_Parent to (folder of the front Finder window) as alias
end tell
tell application "System Events"
set file_List to get the name of every disk item of file_Parent
end tell
set x to file_Suffix
set file_New to file_Prefix & x & file_Extension
repeat
if file_New is in file_List then
set x to x + 1
set file_New to file_Prefix & x & file_Extension
else
return file_New
end if
end repeat
And here's the AppleScript in the corrected macro:
AppleScript-image
set kmInst to system attribute "KMINSTANCE"
tell application "Keyboard Maestro Engine"
set file_Parent to getvariable "local_Parent" instance kmInst
set file_Prefix to getvariable "local_Prefix" instance kmInst
set file_Suffix to getvariable "local_Suffix" instance kmInst
set file_Extension to getvariable "local_Extension" instance kmInst
end tell
if file_Extension is not "" then
set file_Extension to "." & file_Extension
end if
tell application "System Events"
set file_List to get the name of every disk item of (file_Parent as POSIX file as alias)
end tell
set x to file_Suffix
set file_New to file_Prefix & x & file_Extension
repeat
if file_New is in file_List then
set x to x + 1
set file_New to file_Prefix & x & file_Extension
else
return file_New
end if
end repeat
